
**Month-over-month growth**

Month-over-month compares a time period to its equivalent in the previous month. Figure 5 shows that Sales PM always corresponds to the Sales Amount of the previous month and does not produce any result at the quarter and at the year levels (only the year level is visible in Figure 5).



Sales PM removes all the filters from the Date table and only filters the Year Month Number column using the previous month:

Sales PM :=

VAR CurrentYearMonthNumber = SELECTEDVALUE ( 'Date'[Year Month Number] )

VAR PreviousYearMonthNumber = CurrentYearMonthNumber - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Month Number] = PreviousYearMonthNumber

    )

RETURN

    Result

The month-over-month growth is computed as an amount in Sales MOM and as a percentage in Sales MOM %:

Sales MOM :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PM]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MOM % :=


DIVIDE (

    [Sales MOM],

    [Sales PM]

)

Month-over-month compares a time period with its equivalent in the previous month.

Sales PM uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters the Date[DateWithSales] column to guarantee a fair comparison of the last period with data. The month-over-month growth is computed as an amount in Sales MOM and as a percentage in Sales MOM %. Both measures use Sales PM to guarantee the same fair comparison:

Sales PM :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, MONTH ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales MOM :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PM]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MOM % :=

DIVIDE (

    [Sales MOM],

    [Sales PM]

)